Overview Package Class Source Class tree Glossary
previous class      next class frames      no frames

UnrealShare.ThingFactory


00001
00002
00003
00004
00005
00006
00007
00008
00009
00010
00011
00012
00013
00014
00015
00016
00017
00018
00019
00020
00021
00022
00023
00024
00025
00026
00027
00028
00029
00030
00031
00032
00033
00034
00035
00036
00037
00038
00039
00040
00041
00042
00043
00044
00045
00046
00047
00048
00049
00050
00051
00052
00053
00054
00055
00056
00057
00058
00059
00060
00061
00062
00063
00064
00065
00066
00067
00068
00069
00070
00071
00072
00073
00074
00075
00076
00077
00078
00079
00080
00081
00082
00083
00084
00085
00086
00087
00088
00089
00090
00091
00092
00093
00094
00095
00096
00097
00098
00099
00100
00101
00102
00103
00104
00105
00106
00107
00108
00109
00110
00111
00112
00113
00114
00115
00116
00117
00118
00119
00120
00121
00122
00123
00124
00125
00126
00127
00128
00129
00130
00131
00132
00133
00134
00135
00136
00137
00138
00139
00140
00141
00142
00143
00144
00145
00146
00147
00148
00149
00150
00151
00152
00153
00154
00155
00156
00157
00158
00159
00160
00161
00162
00163
00164
00165
00166
00167
00168
00169
00170
00171
00172
00173
00174
00175
00176
00177
00178
//=============================================================================
// ThingFactory.
//=============================================================================
class ThingFactory expands Keypoint;

var() class<actor> prototype;   // the template class
var() int maxitems; // max number of items from this factory at any time
var   int   numitems;   // current number of items from this factory
var int numspots;       // number of spawnspots
var() int capacity;     // max number of items ever buildable (-1 = no limit)
var() float interval;   // average time interval between spawnings
var() name  itemtag;    // tag given to items produced at this factory
var() bool  bFalling;   // non-pawn items spawned should be set to falling

var() enum EDistribution
{
    DIST_Constant,
    DIST_Uniform,
    DIST_Gaussian
}
timeDistribution;

var() bool bOnlyPlayerTouched; //only player can trigger it
var() bool bCovert;     //only do hidden spawns
var() bool bStoppable;  //stops producing when untouched
var Spawnpoint spawnspot[16]; //possible start locations

function PostBeginPlay()
{
    local Spawnpoint newspot;
    
    Super.PostBeginPlay();
    numspots = 0;
    numitems = 0;
    foreach AllActors( class 'Spawnpoint', newspot, tag )
    {
        if (numspots < 16)
        {
            spawnspot[numspots] = newspot;
            newspot.factory = self;
            numspots += 1;
        }
    }
    if (itemtag == '')
        itemtag = 'MadeInUSA';
}   


function StartBuilding()
{
}

Auto State Waiting
{
    function Trigger( actor Other, pawn EventInstigator )
    {
        local Actor A;

        if ( Event != '' )
            ForEach AllActors( class 'Actor', A, Event)
                A.Trigger(self, EventInstigator);
        GotoState('Spawning');
    }
        
    function Touch(Actor Other)
    {
        local pawn otherpawn;
    
        otherpawn = Pawn(Other);
        if ( (otherpawn != None) && (!bOnlyPlayerTouched || otherpawn.bIsPlayer) )
            Trigger(other, otherPawn);
    }
}

State Spawning
{
    function UnTouch(Actor Other)
    {
        local int i;
        if (bStoppable)
        {
            //check if some other pawn still touching
            for (i=0;i<4;i++)
                if ( (pawn(Touching[i]) != None) && (!bOnlyPlayerTouched || pawn(Touching[i]).bIsPlayer) )
                    return;
            GotoState('Waiting');
        }
    }

    function Trigger(actor Other, pawn EventInstigator)
    {
        //only if Other is from this factory
        if ( Other.class != prototype )
            return;
            
        numitems--;
        if (numitems < maxitems)
            StartBuilding();
    }

    function bool trySpawn(int start, int end)
    {
        local int i;
        local bool done;

        done = false;
        i = start;
        while (i < end)
        {
            if (spawnspot[i].Create())
            {
                done = true;
                i = end;
                capacity--;
                numitems++;
                if (capacity == 0)
                    GotoState('Finished');
            }
            i++;
        }
        
        return done;
    }
        
    function Timer()
    {
        local int start;
        
        if (numitems < maxitems)
        {
            //pick a spawn point
            start = Rand(numspots);
            if ( !trySpawn(start, numspots) )
                trySpawn(0, start);
        }
            
        if (numitems < maxitems)
            StartBuilding();
    }

    Function StartBuilding()
    {
        local float nextTime;
        if (timeDistribution == DIST_Constant)
            nextTime = interval;
        else if (timeDistribution == DIST_Uniform)
            nextTime = 2 * FRand() * interval;
        else //timeDistribution is gaussian
            nextTime = 0.5 * (FRand() + FRand() + FRand() + FRand()) * interval;
            
        if (capacity > 0)
            SetTimer(nextTime, false);
    }

    function BeginState()
    {
        if ( !bStoppable )
            Disable('UnTouch');
    }

Begin:
    Timer();
}

state Finished
{
}   

defaultproperties
{
     maxitems=1
     capacity=1000000
     interval=1.000000
     bFalling=True
     bStatic=False
     bCollideActors=True
}

Overview Package Class Source Class tree Glossary
previous class      next class frames      no frames
Class file time: Sun 21/2/2010 23:48:40.000 - Creation time: Sun 21/2/2010 23:49:53.942 - Created with UnCodeX