Overview Package Class Source Class tree Glossary
previous class      next class frames      no frames

UnrealShare.HorseFlySwarm


00001
00002
00003
00004
00005
00006
00007
00008
00009
00010
00011
00012
00013
00014
00015
00016
00017
00018
00019
00020
00021
00022
00023
00024
00025
00026
00027
00028
00029
00030
00031
00032
00033
00034
00035
00036
00037
00038
00039
00040
00041
00042
00043
00044
00045
00046
00047
00048
00049
00050
00051
00052
00053
00054
00055
00056
00057
00058
00059
00060
00061
00062
00063
00064
00065
00066
00067
00068
00069
00070
00071
00072
00073
00074
00075
00076
00077
00078
00079
00080
00081
00082
00083
00084
00085
00086
00087
00088
00089
00090
00091
00092
00093
00094
00095
00096
00097
00098
00099
00100
00101
00102
00103
00104
00105
//=============================================================================
// HorseFlySwarm.
//=============================================================================
class HorseFlySwarm expands FlockMasterPawn;

var()   byte    swarmsize; //number of horseflies in swarm
var     byte    totalflies;
var()   bool    bOnlyIfEnemy;
var()   float   swarmradius;
    
function PreBeginPlay()
{
    totalflies = swarmsize;
    Super.PreBeginPlay();
}

singular function ZoneChange( ZoneInfo NewZone )
{
    if (NewZone.bWaterZone /* || NewZone.bPainZone */)
    {
        SetLocation(OldLocation);
        Velocity = vect(0,0,0);
        Acceleration = vect(0,0,0);
        MoveTimer = -1.0;
        Enemy = None;
    }
}

function SpawnFlies()
{
    while (swarmsize > 0)
    {
        swarmsize--;
        spawn(class 'horsefly',self,'', Location + VRand() * CollisionRadius);
    }
}

auto state stasis
{
ignores EncroachedBy;
    
    function SeePlayer(Actor SeenPlayer)
    {
        enemy = Pawn(SeenPlayer);
        SpawnFlies();
        Gotostate('wandering');
    }

Begin:
    SetPhysics(PHYS_None);
}       

state wandering
{
ignores EncroachedBy;

    function SeePlayer(Actor SeenPlayer)
    {
        local actor newfly;
        Enemy = Pawn(SeenPlayer);
        SpawnFlies();
        Disable('SeePlayer');
        Enable('EnemyNotVisible');
    }

    function EnemyNotVisible()
    {
        Enemy = None;
        Disable('EnemyNotVisible');
    }
    
Begin:
    SetPhysics(PHYS_Flying);

Wander:
    if (Enemy == None)
        Enable('SeePlayer');
        
    if ( (Enemy != None) && !Enemy.Region.Zone.bWaterZone  && !Enemy.Region.Zone.bPainZone )
    {
        MoveToward(Enemy);
        sleep(2 * FRand());
    }   
    else
    {
        Destination = Location + VRand() * 1000;
        Destination.Z = 0.5 * (Destination.Z + Location.Z);
        MoveTo(Destination);
    }
    Goto('Wander');
}

defaultproperties
{
     swarmsize=20
     bOnlyIfEnemy=True
     swarmradius=120.000000
     GroundSpeed=200.000000
     AirSpeed=200.000000
     JumpZ=-1.000000
     SightRadius=2000.000000
     PeripheralVision=-5.000000
     bHidden=True
}

Overview Package Class Source Class tree Glossary
previous class      next class frames      no frames
Class file time: Sun 21/2/2010 23:48:40.000 - Creation time: Sun 21/2/2010 23:49:52.023 - Created with UnCodeX