Overview Package Class Source Class tree Glossary
previous class      next class frames      no frames

UnrealI.Squid


00001
00002
00003
00004
00005
00006
00007
00008
00009
00010
00011
00012
00013
00014
00015
00016
00017
00018
00019
00020
00021
00022
00023
00024
00025
00026
00027
00028
00029
00030
00031
00032
00033
00034
00035
00036
00037
00038
00039
00040
00041
00042
00043
00044
00045
00046
00047
00048
00049
00050
00051
00052
00053
00054
00055
00056
00057
00058
00059
00060
00061
00062
00063
00064
00065
00066
00067
00068
00069
00070
00071
00072
00073
00074
00075
00076
00077
00078
00079
00080
00081
00082
00083
00084
00085
00086
00087
00088
00089
00090
00091
00092
00093
00094
00095
00096
00097
00098
00099
00100
00101
00102
00103
00104
00105
00106
00107
00108
00109
00110
00111
00112
00113
00114
00115
00116
00117
00118
00119
00120
00121
00122
00123
00124
00125
00126
00127
00128
00129
00130
00131
00132
00133
00134
00135
00136
00137
00138
00139
00140
00141
00142
00143
00144
00145
00146
00147
00148
00149
00150
00151
00152
00153
00154
00155
00156
00157
00158
00159
00160
00161
00162
00163
00164
00165
00166
00167
00168
00169
00170
00171
00172
00173
00174
00175
00176
00177
00178
00179
00180
00181
00182
00183
00184
00185
00186
00187
00188
00189
00190
00191
00192
00193
00194
00195
00196
00197
00198
00199
00200
00201
00202
00203
00204
00205
00206
00207
00208
00209
00210
00211
00212
00213
00214
00215
00216
00217
00218
00219
00220
00221
00222
00223
00224
00225
00226
00227
00228
00229
00230
00231
00232
00233
00234
00235
00236
00237
00238
00239
00240
00241
00242
00243
00244
00245
00246
00247
00248
00249
00250
00251
00252
00253
00254
00255
00256
00257
00258
00259
00260
00261
00262
00263
00264
00265
00266
00267
00268
00269
00270
00271
00272
00273
00274
00275
00276
00277
00278
00279
00280
00281
00282
00283
00284
00285
00286
00287
00288
00289
00290
00291
00292
00293
00294
00295
00296
00297
00298
00299
00300
00301
00302
00303
00304
00305
00306
00307
00308
00309
00310
00311
00312
00313
00314
00315
00316
00317
00318
00319
00320
00321
00322
00323
00324
00325
00326
00327
00328
00329
00330
00331
00332
00333
00334
00335
00336
00337
00338
00339
00340
00341
00342
00343
00344
00345
00346
00347
00348
00349
00350
00351
00352
00353
00354
00355
00356
00357
00358
00359
00360
00361
00362
00363
00364
00365
00366
00367
00368
00369
00370
00371
00372
00373
00374
00375
00376
00377
00378
00379
00380
00381
00382
00383
00384
00385
00386
00387
00388
00389
00390
00391
00392
00393
00394
00395
00396
00397
00398
00399
00400
00401
00402
00403
00404
00405
00406
00407
00408
00409
00410
00411
00412
00413
00414
00415
00416
00417
00418
00419
00420
00421
00422
00423
00424
00425
00426
00427
00428
00429
00430
00431
00432
00433
00434
00435
00436
00437
00438
00439
00440
00441
00442
00443
00444
00445
00446
00447
00448
00449
00450
00451
00452
00453
00454
00455
00456
00457
00458
//=============================================================================
// Squid.
//=============================================================================
class Squid expands ScriptedPawn;

#exec MESH IMPORT MESH=Squid1 ANIVFILE=MODELS\squid_a.3D DATAFILE=MODELS\squid_d.3D X=0 Y=0 Z=0
#exec MESH ORIGIN MESH=Squid1 X=0 Y=0 Z=-100 YAW=-64 ROLL=-64 

#exec MESH SEQUENCE MESH=squid1 SEQ=All		STARTFRAME=0	NUMFRAMES=142
#exec MESH SEQUENCE MESH=squid1 SEQ=Dead1	STARTFRAME=0	NUMFRAMES=21	RATE=15
#exec MESH SEQUENCE MESH=squid1 SEQ=TakeHit STARTFRAME=0	NUMFRAMES=1
#exec MESH SEQUENCE MESH=squid1 SEQ=Fighter STARTFRAME=21   NUMFRAMES=15	RATE=15
#exec MESH SEQUENCE MESH=squid1 SEQ=Grab	STARTFRAME=36   NUMFRAMES=13	RATE=15  Group=Attack
#exec MESH SEQUENCE MESH=squid1 SEQ=Hold	STARTFRAME=49   NUMFRAMES=15	RATE=15
#exec MESH SEQUENCE MESH=squid1 SEQ=Release STARTFRAME=64   NUMFRAMES=6
#exec MESH SEQUENCE MESH=squid1 SEQ=Slap	STARTFRAME=70   NUMFRAMES=13	RATE=15  Group=Attack
#exec MESH SEQUENCE MESH=squid1 SEQ=Spin	STARTFRAME=83   NUMFRAMES=10	RATE=15
#exec MESH SEQUENCE MESH=squid1 SEQ=Swim	STARTFRAME=93   NUMFRAMES=20	RATE=15
#exec MESH SEQUENCE MESH=squid1 SEQ=Thrust  STARTFRAME=113  NUMFRAMES=18	RATE=15  Group=Attack
#exec MESH SEQUENCE MESH=squid1 SEQ=Turn	STARTFRAME=131  NUMFRAMES=11	RATE=15

#exec TEXTURE IMPORT NAME=JSquid1 FILE=MODELS\squid.PCX GROUP=Skins 
#exec MESHMAP SCALE MESHMAP=Squid1 X=0.1 Y=0.1 Z=0.2
#exec MESHMAP SETTEXTURE MESHMAP=squid1 NUM=1 TEXTURE=Jsquid1

#exec MESH NOTIFY MESH=Squid1 SEQ=Grab TIME=0.54 FUNCTION=GrabTarget
#exec MESH NOTIFY MESH=Squid1 SEQ=Slap TIME=0.36 FUNCTION=SlapTarget
#exec MESH NOTIFY MESH=Squid1 SEQ=Thrust TIME=0.23 FUNCTION=ThrustTarget

#exec AUDIO IMPORT FILE="Sounds\Squid\amb1sq.WAV" NAME="amb1sq" GROUP="Squid"
#exec AUDIO IMPORT FILE="Sounds\Squid\death1sq.WAV" NAME="death1sq" GROUP="Squid"
#exec AUDIO IMPORT FILE="Sounds\Squid\grab1sq.WAV" NAME="grab1sq" GROUP="Squid"
#exec AUDIO IMPORT FILE="Sounds\Squid\hit1sq.WAV" NAME="hit1sq" GROUP="Squid"
#exec AUDIO IMPORT FILE="Sounds\Squid\slap1sq.WAV" NAME="slap1sq" GROUP="Squid"
#exec AUDIO IMPORT FILE="Sounds\Squid\thrust1sq.WAV" NAME="thrust1sq" GROUP="Squid"
#exec AUDIO IMPORT FILE="Sounds\Squid\injur1sq.WAV" NAME="injur1sq" GROUP="Squid"
#exec AUDIO IMPORT FILE="Sounds\Squid\injur2sq.WAV" NAME="injur2sq" GROUP="Squid"
#exec AUDIO IMPORT FILE="Sounds\Squid\turn1sq.WAV" NAME="turn1sq" GROUP="Squid"

//-----------------------------------------------------------------------------
// Squid variables.

// Attack damage.
var() byte
    ThrustDamage,       // Basic damage done by bite.
    SlapDamage;

var(Sounds) sound thrust;
var(Sounds) sound slapgrabhit;
var(Sounds) sound thrusthit;
var(Sounds) sound slap;
var(Sounds) sound turn;
var(Sounds) sound grab;
var(Sounds) sound spin;
var(Sounds) sound flop;

//-----------------------------------------------------------------------------
// Squid functions.

function ZoneChange(ZoneInfo newZone)
{
    local vector start, checkpoint, HitNormal, HitLocation;
    local actor HitActor;
    
    if ( newZone.bWaterZone )
    {
        if (Physics != PHYS_Swimming)
            setPhysics(PHYS_Swimming);
    }
    else if (Physics == PHYS_Swimming)
    {
        SetPhysics(PHYS_Falling);
        MoveTimer = -1.0;
        GotoState('Flopping');
    }
}

function PreSetMovement()
{
    bCanJump = true;
    bCanWalk = false;
    bCanSwim = true;
    bCanFly = false;
    MinHitWall = -0.6;
    bCanOpenDoors = false;
    bCanDoSpecial = false;
}

function SetMovementPhysics()
{
    if (Region.Zone.bWaterZone)
        SetPhysics(PHYS_Swimming);
    else
    {
        SetPhysics(PHYS_Falling);
        MoveTimer = -1.0;
        GotoState('Flopping');
    } 
}

function PlayWaiting()
    {
    LoopAnim('Fighter', 0.1 + 0.3 * FRand());
    }

function PlayPatrolStop()
    {
    LoopAnim('Fighter', 0.1 + 0.3 * FRand());
    }

function PlayWaitingAmbush()
    {
    LoopAnim('Fighter', 0.1 + 0.3 * FRand());
    }

function PlayChallenge()
{
    PlayAnim('Fighter', 0.4, 0.2);
}

function TweenToFighter(float tweentime)
{
    TweenAnim('Fighter', tweentime);
}

function TweenToRunning(float tweentime)
{
    if ( (AnimSequence != 'Swim') || !bAnimLoop )
        TweenAnim('Swim', tweentime);
}

function TweenToWalking(float tweentime)
{
    if ( (AnimSequence != 'Swim') || !bAnimLoop )
        TweenAnim('Swim', tweentime);
}

function TweenToWaiting(float tweentime)
{
    PlayAnim('Fighter', 0.2 + 0.8 * FRand(), 0.3);
}

function TweenToPatrolStop(float tweentime)
{
    TweenAnim('Fighter', tweentime);
}

function PlayRunning()
{
    if ( ((AnimSequence == 'Spin') && (FRand() < 0.8)) || (FRand() < 0.06) )
        LoopAnim('Spin');
    else
        LoopAnim('Swim', -0.8/WaterSpeed,, 0.4);
}

function PlayWalking()
{
    LoopAnim('Swim', -0.8/WaterSpeed,, 0.4);
}

function PlayThreatening()
{
    if ( FRand() < 0.6 )
        PlayAnim('Swim', 0.4);
    else
    {
        PlaySound(Spin, SLOT_Interact);
        PlayAnim('Spin', 0.4);
    }
}

function PlayTurning()
{
    PlaySound(turn, SLOT_Interact);
    LoopAnim('Turn', 0.4);
}

function PlayDying(name DamageType, vector HitLocation)
{
    PlaySound(Die, SLOT_Talk, 4 * TransientSoundVolume);
    PlayAnim('Dead1', 0.7, 0.1);
}

function PlayTakeHit(float tweentime, vector HitLoc, int damage)
{
    TweenAnim('TakeHit', tweentime);
}

function TweenToFalling()
{
    DesiredRotation = Rotation;
    DesiredRotation.Pitch = 0;
    TweenAnim('Spin', 0.2);
}

function PlayInAir()
{
    LoopAnim('Fighter', 0.7);
}

function PlayLanded(float impactVel)
{
    TweenAnim('Spin', 0.2);
}

function PlayVictoryDance()
{
    PlayAnim('grab', 0.6, 0.1);
    PlaySound(Grab, SLOT_Interact);
}


function GrabTarget()
{
    if ( MeleeDamageTarget(SlapDamage, (SlapDamage * 1500.0 * Normal(Location - Target.Location))) )
        PlaySound(SlapGrabHit, SLOT_Interact);
}

function SlapTarget()
{
    if ( MeleeDamageTarget(SlapDamage, (SlapDamage * 1500.0 * Normal(Target.Location - Location))) )
        PlaySound(SlapGrabHit, SLOT_Interact);
}

function ThrustTarget()
{
    if ( MeleeDamageTarget(ThrustDamage, (ThrustDamage * 1500.0 * Normal(Target.Location - Location))) )
        PlaySound(ThrustHit, SLOT_Interact);
}
    
//FIXME - hold (turn off client's physics???
function PlayMeleeAttack()
{
    local float decision;
    decision = FRand();
    if (decision < 0.35)
    {
        PlaySound(Thrust, SLOT_Interact);
        PlayAnim('Thrust', 0.8);
    }
    if (decision < 0.7)
    {
        PlaySound(Slap, SLOT_Interact);
        PlayAnim('Slap', 0.8);
    }
    else 
    {
        PlaySound(Grab, SLOT_Interact);
        PlayAnim('Grab'); 
    }
}


function bool MeleeDamageTarget(int hitdamage, vector pushdir)
    {
    local vector HitLocation, HitNormal, TargetPoint;
    local float TargetDist;
    local actor HitActor;
    local bool result;
    
    result = false;
    TargetDist = VSize(Target.Location - Location);
    Acceleration = AccelRate * (Target.Location - Location)/TargetDist;
    If (TargetDist <= (MeleeRange * 1.4 + Target.CollisionRadius + CollisionRadius)) //still in melee range
        {
        TargetPoint = Location - TargetDist * vector(Rotation); 
        TargetPoint.Z = FMin(TargetPoint.Z, Target.Location.Z + Target.CollisionHeight);
        TargetPoint.Z = FMax(TargetPoint.Z, Target.Location.Z - Target.CollisionHeight);
        HitActor = Trace(HitLocation, HitNormal, TargetPoint, Location, true);
        If (HitActor == Target)
            {   
            Target.TakeDamage(hitdamage, Self,HitLocation, pushdir, 'hacked');
            result = true;
            }
        }
    return result;
    }


State Flopping
{
ignores seeplayer, hearnoise, enemynotvisible, hitwall;     
    function Timer()
    {
        SetPhysics(PHYS_Falling);
        Velocity = 200 * VRand();
        Velocity.Z = 170 + 200 * FRand();
        DesiredRotation.Pitch = Rand(8192) - 4096;
        DesiredRotation.Yaw = Rand(65535);
    }
    
    function ZoneChange( ZoneInfo NewZone )
    {
        local Rotator newRotation;
        if (NewZone.bWaterZone)
        {
            newRotation = Rotation;
            newRotation.Roll = 0;
            SetRotation(newRotation);
            SetPhysics(PHYS_Swimming);
            GotoState('Attacking');
        }
        else if (Physics != PHYS_Falling)
            SetPhysics(PHYS_Falling);
    }
    
    function Landed(vector HitNormal)
    {
        SetPhysics(PHYS_None);
        DesiredRotation.Pitch = 0;
        SetTimer(0.3 + FRand(), false);
    }
    
    function AnimEnd()
    {
        PlayAnim('Spin', 0.7);
    }

Begin:
    SetTimer(0.3 + FRand(), false);
    TweenAnim('Flopping', 0.7);
}

state TacticalMove
{
ignores SeePlayer, HearNoise;

    function Timer()
    {
        Spawn(class'BigBlackSmoke');
    }
    
    function BeginState()
    {
        SetTimer(0.2, true);
        Super.BeginState();
    }
}

//squid has own melee attack because he faces away from his target when attacking
state MeleeAttack
{
ignores SeePlayer, HearNoise, Bump;
    function TakeDamage( int Damage, Pawn instigatedBy, Vector hitlocation, 
                            Vector momentum, name damageType)
    {
        Global.TakeDamage(Damage, instigatedBy, hitlocation, momentum, damageType);
        if ( health <= 0 )
            return;
        if (NextState == 'TakeHit')
        {
            NextState = 'MeleeAttack';
            NextLabel = 'Begin';
        }
    }

    function KeepAttacking()
    {
        bReadyToAttack = true;
        if ( (Target == None) 
            || ((Pawn(Target) != None) && (Pawn(Target).Health == 0)) )
            GotoState('Attacking');
        else if (VSize(Target.Location - Location) > (0.9 * MeleeRange + Target.CollisionRadius + CollisionRadius)) 
            GotoState('TacticalMove', 'NoCharge');
    }

    function EnemyNotVisible()
    {
        //log("enemy not visible");
        GotoState('Attacking');
    }

    function AnimEnd()
    {
        GotoState('MeleeAttack', 'DoneAttacking');
    }
    
    function BeginState()
    {
        Disable('AnimEnd');
        bCanStrafe = true; //so he can turn in place
    }

    function EndState()
    {
        bCanStrafe = false;
    }
    
Begin:
    if (Target == None)
        Target = Enemy;
    
FaceTarget:
    Acceleration = Vect(0,0,0);
    if (NeedToTurn(2 * Location - Target.Location))
    {
        PlayTurning();
        TurnTo(2 * Location - Target.Location);
        TweenToFighter(0.15);
    }
    else if ( (5 - Skill) * FRand() > 3 ) 
    {
        DesiredRotation = Rotator(Location - Target.Location);
        PlayChallenge(); 
    }
    
    FinishAnim();
        
    if (VSize(Location - Target.Location) > MeleeRange + CollisionRadius + Target.CollisionRadius)
        GotoState('Attacking'); 

ReadyToAttack:
    DesiredRotation = Rotator(Location - Target.Location);
    PlayMeleeAttack();
    Enable('AnimEnd');
Attacking:
    TurnTo(2 * Location - Target.Location);
    Goto('Attacking');
DoneAttacking:
    Disable('AnimEnd');
    KeepAttacking();
    Goto('FaceTarget');
}

    

defaultproperties
{
     ThrustDamage=35
     SlapDamage=30
     Thrust=Sound'UnrealI.Squid.thrust1sq'
     slapgrabhit=Sound'UnrealI.Squid.hit1sq'
     thrusthit=Sound'UnrealI.Squid.hit1sq'
     Slap=Sound'UnrealI.Squid.slap1sq'
     Turn=Sound'UnrealI.Squid.turn1sq'
     Grab=Sound'UnrealI.Squid.grab1sq'
     Aggressiveness=0.800000
     MeleeRange=70.000000
     GroundSpeed=0.000000
     WaterSpeed=260.000000
     AirSpeed=0.000000
     SightRadius=2000.000000
     PeripheralVision=-0.500000
     Health=260
     Intelligence=BRAINS_REPTILE
     HitSound1=Sound'UnrealI.Squid.injur1sq'
     HitSound2=Sound'UnrealI.Squid.injur2sq'
     Die=Sound'UnrealI.Squid.death1sq'
     DrawType=DT_Mesh
     Mesh=Mesh'UnrealI.Squid1'
     AmbientSound=Sound'UnrealI.Squid.amb1sq'
     CollisionRadius=40.000000
     CollisionHeight=60.000000
     Mass=200.000000
     Buoyancy=200.000000
     RotationRate=(Pitch=13000,Roll=13000)
}

Overview Package Class Source Class tree Glossary
previous class      next class frames      no frames
Class file time: Sun 21/2/2010 23:48:40.000 - Creation time: Sun 21/2/2010 23:49:53.786 - Created with UnCodeX