Overview Package Class Source Class tree Glossary
previous class      next class frames      no frames

Engine.Ammo


00001
00002
00003
00004
00005
00006
00007
00008
00009
00010
00011
00012
00013
00014
00015
00016
00017
00018
00019
00020
00021
00022
00023
00024
00025
00026
00027
00028
00029
00030
00031
00032
00033
00034
00035
00036
00037
00038
00039
00040
00041
00042
00043
00044
00045
00046
00047
00048
00049
00050
00051
00052
00053
00054
00055
00056
00057
00058
00059
00060
00061
00062
00063
00064
00065
00066
00067
00068
00069
00070
00071
00072
00073
00074
00075
00076
00077
00078
00079
00080
00081
00082
00083
00084
00085
00086
00087
00088
00089
00090
00091
00092
00093
00094
00095
00096
00097
00098
00099
00100
00101
00102
00103
00104
00105
00106
00107
00108
00109
00110
00111
00112
00113
00114
00115
00116
//=============================================================================
// Ammo.
//=============================================================================
class Ammo expands Pickup
    abstract;

#exec Texture Import File=Textures\Ammo.pcx Name=S_Ammo Mips=Off Flags=2

var() travel int AmmoAmount;
var() travel int MaxAmmo;
var() class<ammo> ParentAmmo;    // Class of ammo to be represented in inventory
var() byte UsedInWeaponSlot[10];
var   ammo  PAmmo;



// Network replication
//
replication
{
    // Things the server should send to the client.
    reliable if( Role==ROLE_Authority && bNetOwner )
        AmmoAmount;
}

event float BotDesireability(Pawn Bot)
{
    local Ammo AlreadyHas;

    if ( ParentAmmo != None )
        AlreadyHas = Ammo(Bot.FindInventoryType(ParentAmmo));
    else
        AlreadyHas = Ammo(Bot.FindInventoryType(Class));
    if ( AlreadyHas == None )
        return (0.35 * MaxDesireability);
    if ( AlreadyHas.AmmoAmount == 0 )
        return MaxDesireability;
    if (AlreadyHas.AmmoAmount >= AlreadyHas.MaxAmmo) 
        return -1;

    return ( MaxDesireability * FMin(1, 0.15 * MaxAmmo/AlreadyHas.AmmoAmount) );
}

function bool HandlePickupQuery( inventory Item )
{
    if ( (class == item.class) || 
        (ClassIsChildOf(item.class, class'Ammo') && (class == Ammo(item).parentammo)) ) 
    {
        if (AmmoAmount==MaxAmmo) return true;
        Pawn(Owner).ClientMessage(item.PickupMessage, 'Pickup');
        item.PlaySound( item.PickupSound );
        AddAmmo(Ammo(item).AmmoAmount);
        item.SetRespawn();
        return true;                
    }
    if ( Inventory == None )
        return false;

    return Inventory.HandlePickupQuery(Item);
}

// This function is called by an actor that wants to use ammo.  
// Return true if ammo exists 
//
function bool UseAmmo(int AmountNeeded)
{
    if (AmmoAmount < AmountNeeded) return False;   // Can't do it
    AmmoAmount -= AmountNeeded;
    return True;
}

// If we can, add ammo and return true.  
// We we are at max ammo, return false
//
function bool AddAmmo(int AmmoToAdd)
{
    If (AmmoAmount >= MaxAmmo) return false;
    AmmoAmount += AmmoToAdd;
    if (AmmoAmount > MaxAmmo) AmmoAmount = MaxAmmo;
    return true;
}

function inventory SpawnCopy( Pawn Other )
{
    local Inventory Copy;

    if ( parentammo != None )
    {
        Copy = spawn(parentammo,Other);
        Copy.Tag           = Tag;
        Copy.Event         = Event;
        Copy.Instigator    = Other;
        Ammo(Copy).AmmoAmount = AmmoAmount;
        Copy.BecomeItem();
        Other.AddInventory( Copy );
        Copy.GotoState('');
        if ( Level.Game.ShouldRespawn(self) )
            GotoState('Sleeping');
        else
            Destroy();
        return Copy;
    }
    Copy = Super.SpawnCopy(Other);
    Ammo(Copy).AmmoAmount = AmmoAmount; 
    return Copy;
}

defaultproperties
{
     PickupMessage="You picked up some ammo."
     RespawnTime=30.000000
     MaxDesireability=0.200000
     Texture=Texture'Engine.S_Ammo'
     bCollideActors=False
}

Overview Package Class Source Class tree Glossary
previous class      next class frames      no frames
Class file time: Sun 21/2/2010 23:48:40.000 - Creation time: Sun 21/2/2010 23:49:51.056 - Created with UnCodeX