Overview Package Class Source Class tree Glossary
previous class      next class frames      no frames

Engine.BroadcastHandler


00001
00002
00003
00004
00005
00006
00007
00008
00009
00010
00011
00012
00013
00014
00015
00016
00017
00018
00019
00020
00021
00022
00023
00024
00025
00026
00027
00028
00029
00030
00031
00032
00033
00034
00035
00036
00037
00038
00039
00040
00041
00042
00043
00044
00045
00046
00047
00048
00049
00050
00051
00052
00053
00054
00055
00056
00057
00058
00059
00060
00061
00062
00063
00064
00065
00066
00067
00068
00069
00070
00071
00072
00073
00074
00075
00076
00077
00078
00079
00080
00081
00082
00083
00084
00085
00086
00087
00088
00089
00090
00091
00092
00093
00094
00095
00096
00097
00098
00099
00100
00101
00102
00103
00104
00105
00106
00107
00108
00109
00110
00111
00112
00113
00114
00115
00116
00117
00118
00119
00120
00121
00122
00123
00124
00125
00126
00127
00128
00129
00130
00131
00132
00133
00134
00135
00136
00137
00138
00139
00140
00141
00142
00143
00144
00145
00146
00147
00148
00149
00150
00151
00152
00153
00154
00155
00156
00157
00158
00159
00160
00161
00162
00163
00164
00165
00166
00167
00168
00169
00170
00171
00172
00173
00174
00175
00176
00177
00178
00179
00180
00181
00182
00183
00184
00185
00186
00187
00188
00189
00190
00191
00192
00193
00194
00195
00196
00197
00198
00199
00200
//=============================================================================
// BroadcastHandler
//
// Message broadcasting is delegated to BroadCastHandler by the GameInfo.  
// The BroadCastHandler handles both text messages (typed by a player) and 
// localized messages (which are identified by a LocalMessage class and id).  
// GameInfos produce localized messages using their DeathMessageClass and 
// GameMessageClass classes.
//
// This is a built-in Unreal class and it shouldn't be modified.
//=============================================================================
class BroadcastHandler extends Info;

var int             SentText;
var config bool     bMuteSpectators;            // Whether spectators are allowed to speak.
var config bool     bPartitionSpectators;           // Whether spectators are can only speak to spectators.

function UpdateSentText()
{
    SentText = 0;
}

/* Whether actor is allowed to broadcast messages now.
*/
function bool AllowsBroadcast( actor broadcaster, int Len )
{
    local PlayerReplicationInfo PRI;
    local GameReplicationInfo GRI;

    GRI = Level.Game.GameReplicationInfo;
    if( !GRI ) return false;

    if ( Pawn(Broadcaster) != None )
        PRI = Pawn(Broadcaster).PlayerReplicationInfo;
    else if ( Controller(Broadcaster) != None )
        PRI = Controller(Broadcaster).PlayerReplicationInfo;

    if ( bMuteSpectators && (PRI != None) && !PRI.bOnlySpectator && (PRI.bIsSpectator && GRI.bMatchHasBegun) )
        return false;

    SentText += Len;
    return ( (Level.Pauser != None) || (SentText < 400) );
}


function BroadcastText( PlayerReplicationInfo SenderPRI, PlayerController Receiver, coerce string Msg, optional name Type, optional sound MessageSound )
{
    Receiver.TeamMessage( SenderPRI, Msg, Type, MessageSound );
}

function BroadcastLocalized( Actor Sender, PlayerController Receiver, class<LocalMessage> Message, optional int Switch, optional PlayerReplicationInfo RelatedPRI_1, optional PlayerReplicationInfo RelatedPRI_2, optional Object OptionalObject )
{
    Receiver.ReceiveLocalizedMessage( Message, Switch, RelatedPRI_1, RelatedPRI_2, OptionalObject );
}

function Broadcast( Actor Sender, coerce string Msg, optional name Type, optional sound MessageSound )
{
    local Controller C;
    local PlayerController P;
    local PlayerReplicationInfo PRI;
    local GameReplicationInfo GRI;

    // see if allowed (limit to prevent spamming)
    if ( !AllowsBroadcast(Sender, Len(Msg)) )
        return;

    GRI = Level.Game.GameReplicationInfo;
    if( !GRI ) return;

    if ( Pawn(Sender) != None )
        PRI = Pawn(Sender).PlayerReplicationInfo;
    else if ( Controller(Sender) != None )
        PRI = Controller(Sender).PlayerReplicationInfo;

    if ( bPartitionSpectators && (PRI != None) && !PRI.bOnlySpectator && (PRI.bIsSpectator && GRI.bMatchHasBegun) )
    {
        For ( C=Level.ControllerList; C!=None; C=C.NextController )
        {
            P = PlayerController(C);
            if ( (P != None) && P.PlayerReplicationInfo.bIsSpectator )
                BroadcastText(PRI, P, Msg, Type, MessageSound);
        }
    }
    else
    {
        For ( C=Level.ControllerList; C!=None; C=C.NextController )
        {
            P = PlayerController(C);
            if ( P != None )
                BroadcastText(PRI, P, Msg, Type, MessageSound);
        }
    }
}

function BroadcastTeam( Controller Sender, coerce string Msg, optional name Type, optional sound MessageSound )
{
    local Controller C;
    local PlayerController P;
    local GameReplicationInfo GRI;

    // see if allowed (limit to prevent spamming)
    if ( !AllowsBroadcast(Sender, Len(Msg)) )
        return;

    GRI = Level.Game.GameReplicationInfo;
    if( !GRI ) return;

    if ( /*bPartitionSpectators && -- always partition for teamsay*/ (Sender != None) && !Sender.PlayerReplicationInfo.bOnlySpectator && (Sender.PlayerReplicationInfo.bIsSpectator && GRI.bMatchHasBegun) )
    {
        For ( C=Level.ControllerList; C!=None; C=C.NextController )
        {
            P = PlayerController(C);
            if ( (P != None) && (P.PlayerReplicationInfo.Team == Sender.PlayerReplicationInfo.Team) && P.PlayerReplicationInfo.bIsSpectator )
                BroadcastText(Sender.PlayerReplicationInfo, P, Msg, Type, MessageSound);
        }
    }
    else
    {
        For ( C=Level.ControllerList; C!=None; C=C.NextController )
        {
            P = PlayerController(C);
            if ( (P != None) && (P.PlayerReplicationInfo.Team == Sender.PlayerReplicationInfo.Team) && !P.PlayerReplicationInfo.bIsSpectator )
                BroadcastText(Sender.PlayerReplicationInfo, P, Msg, Type, MessageSound);
        }
    }
}

/*
 Broadcast a localized message to all players.
 Most messages deal with 0 to 2 related PRIs.
 The LocalMessage class defines how the PRI's and optional actor are used.
*/
event AllowBroadcastLocalized( actor Sender, class<LocalMessage> Message, optional int Switch, optional PlayerReplicationInfo RelatedPRI_1, optional PlayerReplicationInfo RelatedPRI_2, optional Object OptionalObject )
{
    local Controller C;
    local PlayerController P;
    local PlayerReplicationInfo PRI;
    local GameReplicationInfo GRI;

    GRI = Level.Game.GameReplicationInfo;
    if( !GRI ) return;

    if ( Pawn(Sender) != None )
        PRI = Pawn(Sender).PlayerReplicationInfo;
    else if ( Controller(Sender) != None )
        PRI = Controller(Sender).PlayerReplicationInfo;

    if ( bPartitionSpectators && (PRI != None) && !PRI.bOnlySpectator && (PRI.bIsSpectator && GRI.bMatchHasBegun) )
    {
        For ( C=Level.ControllerList; C!=None; C=C.NextController )
        {
            P = PlayerController(C);
            if ( (P != None) && P.PlayerReplicationInfo.bIsSpectator )
                BroadcastLocalized(Sender, P, Message, Switch, RelatedPRI_1, RelatedPRI_2, OptionalObject);
        }
    }
    else
    {
        For ( C=Level.ControllerList; C!=None; C=C.NextController )
        {
            P = PlayerController(C);
            if ( P != None )
                BroadcastLocalized(Sender, P, Message, Switch, RelatedPRI_1, RelatedPRI_2, OptionalObject);
        }
    }
}

function BroadcastLocalizedTeam( Controller Sender, class<LocalMessage> Message, optional int Switch, optional PlayerReplicationInfo RelatedPRI_1, optional PlayerReplicationInfo RelatedPRI_2, optional Object OptionalObject )
{
    local Controller C;
    local PlayerController P;
    local GameReplicationInfo GRI;

    GRI = Level.Game.GameReplicationInfo;
    if( !GRI ) return;

    if ( /*bPartitionSpectators && -- always partition for teamsay*/ (Sender != None) && !Sender.PlayerReplicationInfo.bOnlySpectator && (Sender.PlayerReplicationInfo.bIsSpectator && GRI.bMatchHasBegun) )
    {
        For ( C=Level.ControllerList; C!=None; C=C.NextController )
        {
            P = PlayerController(C);
            if ( (P != None) && (P.PlayerReplicationInfo.Team == Sender.PlayerReplicationInfo.Team) && P.PlayerReplicationInfo.bIsSpectator )
                BroadcastLocalized(Sender, P, Message, Switch, RelatedPRI_1, RelatedPRI_2, OptionalObject);
        }
    }
    else
    {
        For ( C=Level.ControllerList; C!=None; C=C.NextController )
        {
            P = PlayerController(C);
            if ( (P != None) && (P.PlayerReplicationInfo.Team == Sender.PlayerReplicationInfo.Team) && !P.PlayerReplicationInfo.bIsSpectator )
                BroadcastLocalized(Sender, P, Message, Switch, RelatedPRI_1, RelatedPRI_2, OptionalObject);
        }
    }
}

defaultproperties
{
}

Overview Package Class Source Class tree Glossary
previous class      next class frames      no frames
Class file time: Fri 3/10/2008 19:00:56.000 - Creation time: Tue 27/4/2010 03:12:43.791 - Created with UnCodeX